0 REM SHOOTER.BAS.txt  Created by Walt Perko 2025

10 DZOP "I"            : REM Initialize DAZZLER
20 DZOP "Z"            : REM Clear screen
30 DZOP "C",1          : REM Color Mode
40 GOSUB 1000
50 REM === DELTA TABLE FOR ANGLES ===
60 DIM DX(7), DY(7)
70 DX(0)=16 : DY(0)=-12   : REM -600
80 DX(1)=18 : DY(1)=-8    : REM -400
90 DX(2)=20 : DY(2)=-4    : REM -200
100 DX(3)=21 : DY(3)=0    : REM  00
110 DX(4)=20 : DY(4)=4    : REM +200
120 DX(5)=18 : DY(5)=8    : REM +400
130 DX(6)=16 : DY(6)=12   : REM +600
140 A = 3                : REM Start angle index (horizontal)
145 GRAV = 1             : REM Gravity value
146 RANDOMIZE            : REM Seed RNG
147 TY = 10 + INT(RND * 215) : REM Initial target center Y
150 GUNX = 0 : GUNY = 128 : REM Gun origin
160 PRINT "8 = UP, 2 = DOWN, F = FIRE, 4 = LESS GRAVITY, 6 = MORE GRAVITY, Q = QUIT"
170 REM === MAIN LOOP ===
180 K$ = INKEY$ : IF K$ = "" THEN 180
190 IF K$ = "Q" THEN END
200 IF K$ = "8" THEN A = A + 1 : IF A > 6 THEN A = 6
210 IF K$ = "2" THEN A = A - 1 : IF A < 0 THEN A = 0
215 IF K$ = "4" THEN GRAV = GRAV - 1 : IF GRAV < 0 THEN GRAV = 0
216 IF K$ = "6" THEN GRAV = GRAV + 1 : IF GRAV > 9 THEN GRAV = 9
220 IF K$ = "F" THEN GOSUB 500 : TY = 10 + INT(RND * 215)
230 DZOP "C",23
240 DZOP "Z"
250 DZOP "P", GUNX, GUNY
260 DZOP "D"
270 DZOP "L", GUNX + DX(A), GUNY + DY(A)
275 GOSUB 400             : REM Draw target
280 PRINT "GRAVITY ="; GRAV
290 GOTO 180

400 REM === DRAW TARGET BAR AT X=255 ===
410 DZOP "C",18
420 FOR T = TY - 10 TO TY + 10
430   DZOP "P",255,T
440   DZOP "D"
450 NEXT T
460 DZOP "C",19
470 DZOP "P",255,TY : DZOP "D"
480 RETURN

500 REM === FIRE BULLET + RECOIL + GRAVITY CONTROLLED ===
510 DZOP "C",17
520 BX = GUNX + DX(A)
530 BY = GUNY + DY(A)
540 DXB = DX(A)
550 DYB = DY(A)
555 VY = DYB
560 FOR I = 1 TO 50
570   DZOP "Z"
580   REM Draw gun barrel (recoiling slightly for I = 1)
590   RX = GUNX - (I = 1) * 3
600   RY = GUNY
610   DZOP "P", RX, RY
620   DZOP "D"
630   DZOP "L", RX + DX(A), RY + DY(A)
635   GOSUB 400    : REM Redraw target
640   REM Draw bullet
650   DZOP "P", BX, BY
660   DZOP "D"
670   BX = BX + DXB
680   VY = VY - GRAV
690   BY = BY + VY
700   DZOP "W", 1
710   IF BY < 0 THEN BY = 0
720   IF BX > 255 THEN BX = 255
730   IF BY > 255 THEN BY = 255
735   IF BX = 255 AND BY = TY THEN GOSUB 800 : I = 999
740   IF BX = 255 OR BY = 0 THEN I = 999
750 NEXT I
760 RETURN

800 REM === YOU WIN MESSAGE ===
810 PRINT
820 PRINT "********************"
830 PRINT "**    YOU WIN!    **"
840 PRINT "********************"
850 GOSUB 2000
860 DZOP "W",20 : RETURN   : REM Pause 2s before continuing

1000 REM SHOOTER WELCOME SCREEN
1030 DZOP "C",1    : REM SET COLOR MODE

1040 REM DISPLAY 'WELCOME'
1050 DZOP "C",23     : REM SET COLOR WHITE
1060 DZOP "P",60,230 : REM POSITION CURSOR
1070 DZOP "S","WELCOME"

1080 REM DISPLAY 'TO'
1090 DZOP "C",23   : REM SET COLOR WHITE
1100 DZOP "P",110,180
1110 DZOP "S","TO"

1120 REM DISPLAY 'SHOOTER'
1130 DZOP "C",17   : REM SET COLOR RED
1140 DZOP "P",55,130
1150 DZOP "S","SHOOTER"

1160 REM DISPLAY 'BY WKP'
1170 DZOP "C",18   : REM SET COLOR GREEN
1180 DZOP "P",70,80
1190 DZOP "S","BY WKP"

1200 REM DISPLAY 'A DZMBASIC'
1210 DZOP "C",20   : REM SET COLOR BLUE
1220 DZOP "P",30,50
1230 DZOP "S","A DZMBASIC"

1240 REM DISPLAY 'PROGRAM'
1250 DZOP "C",20   : REM SET COLOR BLUE
1260 DZOP "P",50,20
1270 DZOP "S","PROGRAM"
1290 RETURN

2000 REM SHOOTER WINNING SCREEN
2030 DZOP "Z"
2040 DZOP "C",1    : REM SET COLOR MODE

2050 REM DISPLAY 'WOW !!!'
2060 DZOP "C",19     : REM SET COLOR YELLOW
2070 DZOP "P",65,230 : REM POSITION CURSOR
2080 DZOP "S","WOW !!!"

2090 REM DISPLAY 'YOU WON'
2100 DZOP "C",18   : REM SET COLOR GREEN
2110 DZOP "P",55,180
2120 DZOP "S","YOU WON"

2130 REM DISPLAY 'SHOOTER'
2140 DZOP "C",17   : REM SET COLOR RED
2150 DZOP "P",60,130
2160 DZOP "S","SHOOTER"

2170 REM DISPLAY 'BY WKP'
2180 DZOP "C",20   : REM SET COLOR BLUE
2190 DZOP "P",70,80
2200 DZOP "S","BY WKP"

2210 REM DISPLAY 'A DZMBASIC'
2220 DZOP "C",20   : REM SET COLOR BLUE
2230 DZOP "P",30,50
2240 DZOP "S","A DZMBASIC"

2250 REM DISPLAY 'PROGRAM'
2260 DZOP "C",20   : REM SET COLOR BLUE
2270 DZOP "P",50,20
2280 DZOP "S","PROGRAM"
2290 RETURN
