0 REM HEPTASPIN.BAS.txt - Rotating 3D Heptagonal Prism

10 DZOP "I"      : REM INIT DAZZLER
20 DZOP "Z"      : REM CLEAR SCREEN
30 DZOP "C",0    : REM BLACK AND WHITE MODE
30 DZOP "C",1    : REM COLOR MODE

40 DIM X(14),Y(14),Z(14)
50 DIM X1(14),Y1(14),Z1(14)
60 DIM PX(14),PY(14)
70 DIM E(21,2)

80 CX = 128 : CY = 128
90 R = 40   : H = 30

100 REM BUILD HEPTAGON TOP AND BOTTOM
110 FOR I = 0 TO 6
120   A = 3.1416 * 2 * I / 7
130   X(I) = R * COS(A)
140   Y(I) = R * SIN(A)
150   Z(I) = H
160   X(I+7) = X(I)
170   Y(I+7) = Y(I)
180   Z(I+7) = -H
190 NEXT I

200 REM DEFINE EDGES
210 FOR I = 0 TO 6
220   E(I,0)     = I                  : E(I,1)     = (I+1) MOD 7          : REM Top face
230   E(I+7,0)   = I+7                : E(I+7,1)   = ((I+1) MOD 7)+7      : REM Bottom face
240   E(I+14,0)  = I                  : E(I+14,1)  = I+7                  : REM Vertical edges
250 NEXT I

260 ANG = 0

270 REM ROTATION LOOP
280 FOR T = 1 TO 1000
285 DZOP "Y"
290   DZOP "Z"

300   ANG = ANG + 10
310   IF ANG >= 360 THEN ANG = ANG - 360
320   RTH = ANG * 3.1416 / 180
330   COSX = COS(RTH) : SINX = SIN(RTH)

340   FOR I = 0 TO 13
350     X1(I) = X(I)
360     Y1(I) = Y(I) * COSX - Z(I) * SINX
370     Z1(I) = Y(I) * SINX + Z(I) * COSX
380     PX(I) = CX + X1(I)
390     PY(I) = CY + Y1(I) - Z1(I)*0.5
400   NEXT I

410   FOR I = 0 TO 20
420     A = E(I,0)
430     B = E(I,1)
440     DZOP "P",INT(PX(A)),INT(PY(A))
450     DZOP "L",INT(PX(B)),INT(PY(B))
460   NEXT I

470   DZOP "W",30  : REM WAIT 3 SECONDS
480 NEXT T

490 GOTO 280
