0 REM 3DCUBE3.BAS.txt - Moving 3D Cube with Smaller Inner Frame
0 REM DBLCUBES.BAS.txt

10 DZOP "I"      : REM Initialize DAZZLER
20 DZOP "Z"      : REM Clear Screen
30 REM DZOP "C",0    : REM Black and White Mode
40 DZOP "C",1    : REM Set Color Mode

100 REM CONSTANTS
110 SIZE = 60
120 OFFSETX = 30
130 OFFSETY = 30
140 INNER = 20

150 XF = 40 : YF = 40  : REM Starting Position
160 DX = 16 : DY = 12  : REM Step Size

200 REM MAIN LOOP
210 GOSUB 5000 : REM Clear Screen
220 GOSUB 1000 : REM Draw Outer Cube
230 GOSUB 2000 : REM Draw Inner Cube
240 GOSUB 6000 : REM Wait

250 XF = XF + DX
260 YF = YF + DY

270 IF XF < 0 OR XF+SIZE+OFFSETX > 255 THEN DX = -DX : XF = XF + DX
280 IF YF < 0 OR YF+SIZE+OFFSETY > 255 THEN DY = -DY : YF = YF + DY

290 GOTO 210

1000 REM DRAW OUTER 3D CUBE AT XF,YF
1010 XB = XF + OFFSETX
1020 YB = YF + OFFSETY
1030 XS = SIZE

1040 X1 = XF
1050 X2 = XF + XS : IF X2 > 255 THEN X2 = 255
1060 Y1 = YF
1070 Y2 = YF + XS : IF Y2 > 255 THEN Y2 = 255

1080 X3 = XB
1090 X4 = XB + XS : IF X4 > 255 THEN X4 = 255
1100 Y3 = YB
1110 Y4 = YB + XS : IF Y4 > 255 THEN Y4 = 255

1120 DZOP "P",X1,Y1 : DZOP "L",X2,Y1
1130 DZOP "P",X2,Y1 : DZOP "L",X2,Y2
1140 DZOP "P",X2,Y2 : DZOP "L",X1,Y2
1150 DZOP "P",X1,Y2 : DZOP "L",X1,Y1

1160 DZOP "P",X3,Y3 : DZOP "L",X4,Y3
1170 DZOP "P",X4,Y3 : DZOP "L",X4,Y4
1180 DZOP "P",X4,Y4 : DZOP "L",X3,Y4
1190 DZOP "P",X3,Y4 : DZOP "L",X3,Y3

1200 DZOP "P",X1,Y1 : DZOP "L",X3,Y3
1210 DZOP "P",X2,Y1 : DZOP "L",X4,Y3
1220 DZOP "P",X2,Y2 : DZOP "L",X4,Y4
1230 DZOP "P",X1,Y2 : DZOP "L",X3,Y4

1235 REM DZOP "C", 17 : REM 0,5,6,7=SGrey 1,3=FGreen 2=SGreen 8,9,10,11,12,13,14,15=SWhite
1236 DZOP "Y"

1240 RETURN

2000 REM DRAW INNER 3D CUBE CENTERED INSIDE OUTER
2010 IXF = XF + (SIZE - INNER)/2
2020 IYF = YF + (SIZE - INNER)/2
2030 IXB = IXF + OFFSETX
2040 IYB = IYF + OFFSETY

2050 XS = INNER

2060 X1 = IXF
2070 X2 = IXF + XS : IF X2 > 255 THEN X2 = 255
2080 Y1 = IYF
2090 Y2 = IYF + XS : IF Y2 > 255 THEN Y2 = 255

2100 X3 = IXB
2110 X4 = IXB + XS : IF X4 > 255 THEN X4 = 255
2120 Y3 = IYB
2130 Y4 = IYB + XS : IF Y4 > 255 THEN Y4 = 255

2140 DZOP "P",X1,Y1 : DZOP "L",X2,Y1
2150 DZOP "P",X2,Y1 : DZOP "L",X2,Y2
2160 DZOP "P",X2,Y2 : DZOP "L",X1,Y2
2170 DZOP "P",X1,Y2 : DZOP "L",X1,Y1

2180 DZOP "P",X3,Y3 : DZOP "L",X4,Y3
2190 DZOP "P",X4,Y3 : DZOP "L",X4,Y4
2200 DZOP "P",X4,Y4 : DZOP "L",X3,Y4
2210 DZOP "P",X3,Y4 : DZOP "L",X3,Y3

2220 DZOP "P",X1,Y1 : DZOP "L",X3,Y3
2230 DZOP "P",X2,Y1 : DZOP "L",X4,Y3
2240 DZOP "P",X2,Y2 : DZOP "L",X4,Y4
2250 DZOP "P",X1,Y2 : DZOP "L",X3,Y4

2255 REM DZOP "C", 17 : REM 0,5,6,7=SGrey 1,3=FGreen 2=SGreen 8,9,10,11,12,13,14,15=SWhite
2256 DZOP "Y"

2260 RETURN

5000 REM CLEAR SCREEN
5010 DZOP "Z"
5020 RETURN

6000 REM ~3 SECOND PAUSE
6010 FOR W = 1 TO 2
6020   FOR P = 1 TO 500 : NEXT P
6030 NEXT W
6040 RETURN
